home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / FNTNS / RAND1.ASM < prev    next >
Assembly Source File  |  1989-01-24  |  3KB  |  67 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAIMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Last Update 16 Apr 87   Version 1.1
  7. ;
  8.                                                                                                                                
  9. ;
  10. ;       RANDOM NUMBER GENERATOR USING A 15 BIT SHIFT REGISTER
  11. ;
  12. ;
  13. ;
  14. ;
  15.         PAGE    132,66,0,10
  16.         ORG     X:0
  17. NSTATE  DS      1               ;STATE OF NOISE GENERATOR (SHIFT REG)
  18.  
  19.         ORG     P:$100
  20. INIT
  21.         MOVE    #$FF,X0         ;INITIAL STATE OF NOISE GENERATOR
  22.         MOVE    X0,X:NSTATE
  23. GET
  24.         DO      #100,_EGET
  25.         JSR     NOISE           ;GENERATE NOISE SAMPLE
  26.         MOVE    X:NSTATE,A      ;GET NOISE
  27.         MOVEP   A1,Y:$FFFF      ;OUTPUT NOISE SAMPLE
  28. _EGET
  29. ;
  30. ;       DONE WITH PROGRAM
  31. ;
  32.         NOP
  33.         NOP
  34.         NOP
  35.         NOP
  36.         NOP
  37.         NOP
  38. ;       NOISE GENERATION ROUTINE.  THIS ROUTINE USES A 15 BIT SHIFT
  39. ;       REGISTER LEFT JUSTIFIED IN THE VARIABLE "NSTATE".  AFTER THE STATE
  40. ;       IS LOADED, IT IS CHECKED TO SEE IF IT IS NORMALIZED.  IF IT IS
  41. ;       NORMALIZED (TOP TWO BITS ARE DIFFERENT), A 1 IS SET AS THE INPUT
  42. ;       TO THE SHIFT REGISTER AND THE REGISTER IS SHIFTED AND SAVED.
  43. ;
  44. ;         B23     B22                            B9      B8
  45. ;        ______________________________________________
  46. ;       | S14   | S13 |                        | S0   |
  47. ;       |       |     |      . . .             |      |<----------
  48. ;       |_______|_____|________________________|_______          |
  49. ;           |      |                                             |
  50. ;            \    /                                              |
  51. ;              XOR                                               |
  52. ;               \_________________________________________________
  53. ;
  54. ;
  55. ;       ASSUMES SCALING MODE IS OFF
  56. ;
  57. NOISE                                   ;DO NOISE GENERATION LOOP
  58.         CLR     B       X:NSTATE,A      ;GET A ZERO IN B
  59.         TST     A   #>$000100,X0        ;CHECK A, GET A 1 IN LSB POSITION
  60.         TNR     X0,B                    ;IF NORMALIZED, THEN XOR=1
  61.         ADD     B,A                     ;SET LSB
  62.         ASL     A                       ;SHIFT BITS
  63.         MOVE    A1,X:NSTATE             ;SAVE STATE
  64.         RTS                             ;RETURN WITH STATE
  65.         END
  66.  
  67.